Grammar

Program

→ HeaderDecl* Declaration* EOF

HeaderDecl

→ ImportDecl | ExportDecl

Used by Program

ImportDecl

→ "import" ImportPath ";"

Used by HeaderDecl

ExportDecl

→ "export" ImportPath ";"

Used by HeaderDecl

ImportPath

→ PathRoot "::" ImportTree

Used by ImportDeclExportDecl

PathRoot

→ "root" | "std" | "self" | "super" | IDENTIFIER

Used by ImportPath

ImportTree

→ ImportItem| IDENTIFIER "::" ImportTree| "{" ImportItem ( "," ImportItem )* ","? "}"| "*"

Used by ImportPath

ImportItem

→ IDENTIFIER ( "as" IDENTIFIER )?

Used by ImportTree

Declaration

→ LetDeclaration| MutDeclaration| FunDeclaration| StructDeclaration| EnumDeclaration| ImplBlock| TraitDeclaration| Statement

Used by ProgramBlock

LetDeclaration

→ "let" IDENTIFIER ( ":" Type )? "=" Expression ";"

Used by Declaration

MutDeclaration

→ "mut" IDENTIFIER ( ":" Type )? "=" Expression ";"

Used by DeclarationForInit

FunDeclaration

→ "pub"? "fun" IDENTIFIER GenericParams? "(" Params? ")" ( "->" Type )? WhereClause? Block

Used by DeclarationImplBlock

StructDeclaration

→ "pub"? "struct" IDENTIFIER GenericParams? WhereClause? "{" StructFields "}"

Used by Declaration

EnumDeclaration

→ "pub"? "enum" IDENTIFIER GenericParams? WhereClause? "{" EnumVariants "}"

Used by Declaration

ImplBlock

→ "impl" ( Type "for" )? Type "{" FunDeclaration* "}"

Used by Declaration

TraitDeclaration

→ "pub"? "aspect" IDENTIFIER "{" TraitMethod* "}"

Used by Declaration

TraitMethod

→ "fun" IDENTIFIER "(" Params? ")" ( "->" Type )? ( Block | ";" )

Used by TraitDeclaration

Params

→ Param ( "," Param )* ","?

Used by FunDeclarationTraitMethodClosureExpression

Param

→ ( "mut" )? "self" | IDENTIFIER ( ":" Type )?

Used by Params

StructFields

→ StructField ( "," StructField )* ","?

Used by StructDeclarationEnumVariant

StructField

→ IDENTIFIER ":" Type

Used by StructFields

EnumVariants

→ EnumVariant ( "," EnumVariant )* ","?

Used by EnumDeclaration

EnumVariant

→ IDENTIFIER ( "{" StructFields "}" )?

Used by EnumVariants

GenericParams

→ "<" GenericParam ( "," GenericParam )* ">"

Used by FunDeclarationStructDeclarationEnumDeclaration

GenericParam

→ IDENTIFIER ( ":" BoundList )? // since v0.7.0; RFC-0034

Used by GenericParams

BoundList

→ Type ( "+" Type )* // since v0.7.0; RFC-0034

Used by GenericParamWhereConstraint

WhereClause

→ "where" WhereConstraint ( "," WhereConstraint )* // since v0.7.0; RFC-0002

Used by FunDeclarationStructDeclarationEnumDeclaration

WhereConstraint

→ IDENTIFIER ":" BoundList // BoundList since v0.7.0; RFC-0034

Used by WhereClause

Statement

→ ExpressionStatement| Block| IfStatement| WhileStatement| ForStatement| LoopStatement| ReturnStatement| BreakStatement| ContinueStatement

Used by Declaration

ExpressionStatement

→ Expression ";"

Used by StatementForInit

Block

→ "{" Declaration* "}"

Used by FunDeclarationTraitMethodStatementIfStatementWhileStatementForStatementLoopStatementIfExpressionLoopExpressionClosureExpression

IfStatement

→ "if" "(" Expression ")" Block ( "else" ( IfStatement | Block ) )?

Used by Statement

WhileStatement

→ "while" "(" Expression ")" Block

Used by Statement

ForStatement

→ "for" "(" ForInit Expression? ";" Expression? ")" Block| "for" "(" "let" IDENTIFIER "in" Expression ")" Block

Used by Statement

ForInit

→ MutDeclaration | ExpressionStatement | ";"

Used by ForStatement

LoopStatement

→ "loop" Block

Used by Statement

ReturnStatement

→ "return" Expression? ";"

Used by Statement

BreakStatement

→ "break" Expression? ";"

Used by Statement

ContinueStatement

→ "continue" ";"

Used by Statement

Expression

→ AssignmentExpression

Used by LetDeclarationMutDeclarationExpressionStatementIfStatementWhileStatementForStatementReturnStatementBreakStatementLValuePostfixExpressionArgumentsPrimaryExpressionFieldInitMatchExpressionMatchArmIfExpression

AssignmentExpression

→ LValue AssignOp AssignmentExpression | LogicalOrExpression

Used by Expression

LValue

→ IDENTIFIER | CallExpression "." IDENTIFIER | CallExpression "[" Expression "]"

Used by AssignmentExpression

AssignOp

→ "=" | "+=" | "-=" | "*=" | "/=" | "%="

Used by AssignmentExpression

LogicalOrExpression

→ LogicalAndExpression ( "||" LogicalAndExpression )*

Used by AssignmentExpression

LogicalAndExpression

→ ComparisonExpression ( "&&" ComparisonExpression )*

Used by LogicalOrExpression

ComparisonExpression

→ TermExpression ( ( ">" | ">=" | "<" | "<=" | "!=" | "==" ) TermExpression )?

Used by LogicalAndExpression

TermExpression

→ FactorExpression ( ( "+" | "-" ) FactorExpression )*

Used by ComparisonExpression

FactorExpression

→ CastExpression ( ( "*" | "/" | "%" ) CastExpression )*

Used by TermExpression

CastExpression

→ AscribeExpression ( "as" Type )*

Used by FactorExpression

AscribeExpression

→ UnaryExpression ( ":" Type )?

Used by CastExpression

UnaryExpression

→ ( "!" | "-" | "*" | "&" | "&mut" ) UnaryExpression | PostfixExpression

Used by AscribeExpression

PostfixExpression

→ PrimaryExpression ( "(" Arguments? ")" | "." IDENTIFIER | "[" Expression "]" | "?" )*

Used by UnaryExpression

Arguments

→ Expression ( "," Expression )* ","?

Used by PostfixExpression

PrimaryExpression

→ INT | FLOAT | STRING | "true" | "false" | "None" | "()"| "(" Expression ( "," Expression )+ ")" // tuple| "(" Expression ")"| "[" ( Expression ( "," Expression )* ","? )? "]" // array literal| "[" Expression ";" INT "]" // repeat construction [expr; N]| Path| StructLiteral| MatchExpression| IfExpression| LoopExpression| ClosureExpression

Used by PostfixExpression

Path

→ ( "root" | "std" | "self" | "super" | IDENTIFIER ) ( "::" IDENTIFIER )*

Used by PrimaryExpressionStructLiteral

StructLiteral

→ Path "{" FieldInit ( "," FieldInit )* ","? "}"

Used by PrimaryExpression

FieldInit

→ IDENTIFIER ( ":" Expression )? // omitting ": Expression" uses the local variable of the same name

Used by StructLiteral

MatchExpression

→ "match" Expression "{" MatchArm ( "," MatchArm )* ","? "}"

Used by PrimaryExpression

MatchArm

→ Pattern ( "if" Expression )? "=>" Expression

Used by MatchExpression

IfExpression

→ "if" "(" Expression ")" Block "else" Block

Used by PrimaryExpression

LoopExpression

→ "loop" Block

Used by PrimaryExpression

ClosureExpression

→ "(" Params? ")" ( "->" Type )? Block

Used by PrimaryExpression

Pattern

→ "_"| "None"| IDENTIFIER| "(" Pattern ( "," Pattern )* ")" // tuple pattern| IDENTIFIER "::" IDENTIFIER ( "{" PatternFields "}" )?| INT | FLOAT | STRING | "true" | "false"

Used by MatchArm

PatternFields

→ IDENTIFIER ( "," IDENTIFIER )*

Used by Pattern

Type

→ IDENTIFIER ( "<" TypeArgs ">" )?| "*" "mut"? Type // regular pointer types| "()"| "(" Type ( "," Type )+ ")" // tuple type| Type "[]" // array shorthand| "[" Type ";" INT "]" // fixed-size array type (since v0.19.0; RFC-0053)| "(" TypeList? ")" "->" Type // function / closure type| "impl" Type // anonymous bounded param; parameter position only (since v0.7.0; RFC-0035)

Used by LetDeclarationMutDeclarationFunDeclarationImplBlockTraitMethodParamStructFieldBoundListCastExpressionAscribeExpressionClosureExpressionTypeArgsTypeList

TypeArgs

→ Type ( "," Type )*

Used by Type

TypeList

→ Type ( "," Type )*

Used by Type